工作中有时候需要将一张表格拆分为若干个新表，如下图为某电商销售信息表，C列为商品邮寄方式，主要分为：EMS、圆通、顺丰、韵达4中快递方式，现在数据需要按照邮寄方式进行拆分，即邮寄方式为EMS一张表、邮寄方式为圆通一张表.... 以此类推。这种需求，如果类别较少的话通过筛选复制到新的工作簿即可完成，但是类别比较多的话，复制粘贴将耗费大量时间，这里我们用VBA批量实现工作簿类别的拆分，代码可复用，类别灵活选择，具有很强的实用性，下面介绍给大家。

代码

话不多说，直接上代码，在Visual Basic 窗口输入以下代码

代码解释：代码主要是利用字典key值的唯一性对工作簿进行拆分。

第3行“c = Application.InputBox("请输入拆分列号:", , 3)”，主要是选择用来拆分的列，默认选择第三列（邮寄方式列），可更改，如第二列订单日期拆分、第四列客户ID拆分等等，灵活根据数据需求去处理；

第10行“Set d = CreateObject("scripting.dictionary")”主要为创建一个字典d；

第11至17行，主要是判断数组中每一行数据的C列是否在字典key中存在，如果不存在，则给key赋值，值为整行内容，如果存在，也给key赋值，值为历史值与当前行值的结合，依次循环，直到数组中内容完结，这样我们就得到了以类别为key，以各类别行内容为值的字典。

后面的代码只要是将字典每个key对应的值保存在一个工作簿中，工作簿的名称用key命名。下图为程序运行后的结果，可以发现，数据已被按照邮寄方式类别拆分成工作簿~

?下面为代码文字部分，方便小伙伴们copy~

Sub 保留表头拆分数据为若干新工作簿() '字典分类拆分工作簿

Dim arr, d As Object, k, t, i&, lc%, rng As Range, c%

c = Application.InputBox("请输入拆分列号:", , 3) '默认选择第三列，可修改

If c = 0 Then Exit Sub

Application.ScreenUpdating = False

Application.DisplayAlerts = False

arr = [a1].CurrentRegion

lc = UBound(arr, 2)

Set rng = [a1].Resize(, lc)

Set d = CreateObject("scripting.dictionary")

For i = 2 To UBound(arr)

If Not d.Exists(arr(i, c)) Then

Set d(arr(i, c)) = Cells(i, 1).Resize(1, lc)

Else

Set d(arr(i, c)) = Union(d(arr(i, c)), Cells(i, 1).Resize(1, lc))

End If

Next

k = d.Keys

t = d.Items

For i = 0 To d.Count - 1

With Workbooks.Add(xlWBATWorksheet)

rng.Copy .Sheets(1).[a1]

t(i).Copy .Sheets(1).[a2]

.SaveAs Filename:=ThisWorkbook.Path & "/" & k(i) & ".xlsx"

.Close

End With

Next

Application.DisplayAlerts = True

Application.ScreenUpdating = True

MsgBox "完毕"

End Sub

     以上就是excel自学教程为您提供excel VBA字典技术_excel按类别拆分工作簿的解读，本文章链接： http://www.5enet.cn/Excel_VBA/77474.html 欢迎分享转载，更多相关资讯请前往VBA